## Tcl8.6.17/Tk8.6.17 Documentation > [incr Tcl] Package Commands, version 4.3.4 > configbody

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

### NAME

itcl::configbody — 公共変数の為の "config" 符号命令を変更する　　　 change the "config" code for a public variable

### 構文 SYNOPSIS

itcl::configbody className::varName body

### 説明 DESCRIPTION

この configbody 命令は､公共変数に結合した構成設定符号命令を定義又は再定義する為に [incr Tcl]級定義の外側で使用される｡公共変数は対象に対し構成設定指定の様に振舞う｡それらは組込み configure 手段を使って級の有効範囲の外で修正され得る｡ それぞれの変数は､変数に結合し､変数が構成設定指定された時に自動的に実行される "config" 符号命令の小片を有することがでる｡ configbody 命令はこの符号命令の本体の定義や再定義に使用できる｡　　　　 The configbody command is used outside of an [incr Tcl] class definition to define or redefine the configuration code associated with a public variable. Public variables act like configuration options for an object. They can be modified outside the class scope using the built-in configure method. Each variable can have a bit of "config" code associate with it that is automatically executed when the variable is configured. The configbody command can be used to define or redefine this body of code.

body 命令のように､この便益は､級定義を別々の "対話機能" 部分と "実装機能" 部分とに分離させることを許容する｡ "対話機能" 部分は､手段や､手続函数や､変数の即値や､共通変数の為の宣言を伴う class 命令である｡ "実装機能" 部分は､body 命令と configbody 命令の並びである｡ もし"実装機能" 部分が別のファイルに保存されている場合､対話的開発を手助けする為に､瑕疵修復しながら何度も源譜として使用され得る｡ emacs 校正譜内の "tcl"様式を使う時､"対話機能" 部分と "実装機能" 部分は同じファイル内に保存されるかもしれない; 不都合修正が進むにつれ､個別の本体は強調され､試験応用譜に送られるかもしれない｡ 　　　 Like the body command, this facility allows a class definition to have separate "interface" and "implementation" parts. The "interface" part is a class command with declarations for methods, procs, instance variables and common variables. The "implementation" part is a series of body and configbody commands. If the "implementation" part is kept in a separate file, it can be sourced again and again as bugs are fixed, to support interactive development. When using the "tcl" mode in the emacs editor, the "interface" and "implementation" parts can be kept in the same file; as bugs are fixed, individual bodies can be highlighted and sent to the test application.

名称 "className::varName" は更新されている公共変数を識別する｡ もし body 文字列が "@" で始まっている時､それは C 言語手続函数の為の記号名として取扱われる｡そうでない場合､Tcl 命令記述譜として取扱われる｡　　　　 The name "className::varName" identifies the public variable being updated. If the body string starts with "@", it is treated as the symbolic name for a C procedure. Otherwise, it is treated as a Tcl command script.

C 言語手続函数の為の記号名は Itcl_RegisterObjC() 経由で手続函数の登録を確定される｡これは通常､解釈実行機能が開始した時に自動的に呼出される Tcl_AppInit() 手続函数内で行われる｡ 次の実施例では､手続函数 My_FooObjCmd() は記号名 "foo" を使って登録される｡ この手続き函数は configbody 内の命令内で "@foo" として参照できる｡　　　　　　 Symbolic names for C procedures are established by registering procedures via Itcl_RegisterObjC(). This is usually done in the Tcl_AppInit() procedure, which is automatically called when the interpreter starts up. In the following example, the procedure `My_FooObjCmd()` is registered with the symbolic name "foo". This procedure can be referenced in the configbody command as "`@foo`".

    int
    Tcl_AppInit(interp)
        Tcl_Interp *interp;     /* Interpreter for application. */
    {
        if (Itcl_Init(interp) == TCL_ERROR) {
            return TCL_ERROR;
        }

        if (Itcl_RegisterObjC(interp, "foo", My_FooObjCmd) != TCL_OK) {
            return TCL_ERROR;
        }
    }

### 用例 EXAMPLE

次の実施例内で､ "File" 級は開いたファイルの具現を定義する｡何時であれ "-name" 指定が構成設定される時､既存のファイルは閉じられ､新しいファイルが開かれる｡ 註意すべきは､公共変数の為の "config" 符号命令は任意指定である｡ 譬えば､ "-access" 指定はそれを有さない｡ 　　　 In the following example, a "File" class is defined to represent open files. Whenever the "-name" option is configured, the existing file is closed, and a new file is opened. Note that the "config" code for a public variable is optional. The "-access" option, for example, does not have it.

    itcl::class File {
        private variable fid ""

        public variable name ""
        public variable access "r"

        constructor {args} {
            eval configure $args
        }
        destructor {
            if {$fid != ""} {
                close $fid
            }
        }

        method get {}
        method put {line}
        method eof {}
    }

    itcl::body File::get {} {
        return [gets $fid]
    }
    itcl::body File::put {line} {
        puts $fid $line
    }
    itcl::body File::eof {} {
        return [::eof $fid]
    }

    itcl::configbody File::name {
        if {$fid != ""} {
            close $fid
        }
        set fid [open $name $access]
    }

    #
    # 動作中の File 級を観察されたい:
    # See the File class in action:
    #
    File x

    x configure -name /etc/passwd
    while {![x eof]} {
        puts "=> [x get]"
    }
    itcl::delete object x

### KEYWORDS

class, object, variable, configure
Copyright © 1993-1998 Lucent Technologies, Inc.