## Tcl9.0.3/Tk9.0.3 Documentation > Tcl Commands > scan

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

  NAME
    scan — sscanf 様式の変換指定を使って文字列を分解する Parse string using conversion specifiers in the style of sscanf
  SYNOPSIS
  緒論 INTRODUCTION
  走査の詳細 DETAILS ON SCANNING
  任意の位置指定子 OPTIONAL POSITIONAL SPECIFIER
  OPTIONAL SIZE MODIFIER
  MANDATORY CONVERSION CHARACTER
    d
    o
    x or X
    b
    u
    i
    c
    s
    e or f or g or E or G
    [chars]
    [^chars]
    n
  ANSI SSCANF との違い 　DIFFERENCES FROM ANSI SSCANF
  用例 EXAMPLES
  SEE ALSO
  KEYWORDS

### NAME

scan — sscanf 様式の変換指定を使って文字列を分解する Parse string using conversion specifiers in the style of sscanf

### SYNOPSIS

scan string format ?varName varName ...?

### 緒論 INTRODUCTION

この命令は入力文字列からANSI C sscanf 手続函数に似た方式で部分文字列を解析し､遂行された変換の個数を返す､但し､いづれかの変換が遂行される前に入力文字列の末尾に到達すると-1を返す｡ string は解析されるべき入力を与え､ format はそれを sscanf の様に % 変換指定を使用して如何に解析するかを指し示す｡それぞれの varName は変数の名前を与える; 部分文字列が string から分解され､それが変換指示子に合致すると､その部分文字列は対応する変数に代入される｡もし､ varName 変数が指定されないと､scan は埋め込み方法で働き､他の場合には変数に保存される筈のデータがリストとして返される｡この埋め込み方法では､いづれかの変換が遂行される前に､入力文字列が末尾に到達すると空文字列が返される｡ 　　　 This command parses substrings from an input string in a fashion similar to the ANSI C sscanf procedure and returns a count of the number of conversions performed, or -1 if the end of the input string is reached before any conversions have been performed. String gives the input to be parsed and format indicates how to parse it, using % conversion specifiers as in sscanf. Each varName gives the name of a variable; when a substring is scanned from string that matches a conversion specifier, the substring is assigned to the corresponding variable. If no varName variables are specified, then scan works in an inline manner, returning the data that would otherwise be stored in the variables as a list. In the inline case, an empty string is returned when the end of the input string is reached before any conversions have been performed.

### 走査の詳細 DETAILS ON SCANNING

scan は string と format を一緒に走査する事により動作する｡もし､ format 中の次の文字が空白又はタブ文字の場合､文字列中の如何なる個数(零も含めて)の空白とも合致する｡それ以外の場合､もし､ % 文字でなければ､ string の次の文字に合致しなければならない｡ format 中に % に遭遇した時は､それは変換指定子の開始を指し示す｡変換指定子は% の後に四つ迄の欄枠を含む: XPG3 方式の位置指定子(又は､ * であれば､変換された値が何かの変数に代入される代りに遺棄されることを指し示す); 最大部分文字列幅を指し示す数値; 寸法の修正子; 変換文字｡変換文字を除きその他の有無は全て任意である Scan operates by scanning string and format together. If the next character in format is a blank or tab then it matches any number of white space characters in string (including zero). Otherwise, if it is not a % character then it must match the next character of string. When a % is encountered in format, it indicates the start of a conversion specifier. A conversion specifier contains up to four fields after the %: a XPG3 position specifier (or a * to indicate the converted value is to be discarded instead of assigned to any variable); a number indicating a maximum substring width; a size modifier; and a conversion character. All of these fields are optional except for the conversion character. The fields that are present must appear in the order given above.

scan が､ format 中に変換指定子を見付けた時､最初に string 中の如何なる空白も跳び越す(変換文字が [ か c でない限り)｡それで､次の入力文字を変換指定子に従って変換し､結果を scan の次の引数によって与えられた変数に保存する｡ When scan finds a conversion specifier in format, it first skips any white-space characters in string (unless the conversion character is [ or c). Then it converts the next input characters according to the conversion specifier and stores the result in the variable given by the next argument to scan.

#### 任意の位置指定子 OPTIONAL POSITIONAL SPECIFIER

もし､ “%2$d” の様に､ % に十進数と $ が続いていると､使用される変数は次に引続いている引数からは採られない｡その代りに､数字が指し示す引数から採る､ここで､1 は第1 varName に相当する｡format の中に何か位置指示子があると､全ての指示子は位置指定でなければならない｡引数リスト上の全ての varName が正確に一つの変換子でなければ不都合が生じるか､埋め込みの場合は､１度だけなら如何なる位置を指定しても良く､空の位置には空文字列が満たされる｡ If the % is followed by a decimal number and a $, as in “%2$d”, then the variable to use is not taken from the next sequential argument. Instead, it is taken from the argument indicated by the number, where 1 corresponds to the first varName. If there are any positional specifiers in format then all of the specifiers must be positional. Every varName on the argument list must correspond to exactly one conversion specifier or an error is generated, or in the inline case, any position can be specified at most once and the empty positions will be filled in with empty strings.

#### OPTIONAL SIZE MODIFIER

寸法の修正子の欄枠は､部分文字列を調べて､一つのTclの整数値にする時にのみ使用する｡寸法の修正子の欄枠は､変数に保存される整数の範囲を指示するか､埋め込みの場合､結果のリスト中の位置を指示する｡ 寸法の修正子として､統語的に適切な値は､ h と l と z と t と q と j と ll と L である｡ h寸法修正子値は､変換指定子内では不存在と等価である｡どちらも保存されるべき範囲は32ビット巾に限定している｡ L寸法修正子はll寸法修正子と等価である｡どちらも保存されるべき整数の範囲を限定してない｡ l(やqやj)寸法修正子は､保存されるべき整数の範囲を､ expr命令のwide()函数によって生成されるのと同じ範囲に限定されている｡ z寸法修正子とt寸法修正子は､ tcl_platform配列のpointerSizeの値によって､ 整数範囲が h寸法修正子又はl寸法修正子の為のものと同じであることを示す｡ The size modifier field is used only when scanning a substring into one of Tcl's integer values. The size modifier field dictates the integer range acceptable to be stored in a variable, or, for the inline case, in a position in the result list. The syntactically valid values for the size modifier are h, l, z, t, q, j, ll, and L. The h size modifier value is equivalent to the absence of a size modifier in the the conversion specifier. Either one indicates the integer range to be stored is limited to the 32-bit range. The L size modifier is equivalent to the ll size modifier. Either one indicates the integer range to be stored is unlimited. The l (or q or j) size modifier indicates that the integer range to be stored is limited to the same range produced by the wide() function of the expr command. The z and t modifiers indicate the integer range to be the same as for either h or l, depending on the value of the pointerSize element of the tcl_platform array.

#### MANDATORY CONVERSION CHARACTER

The following conversion characters are supported:

d
  入力部分文字列は十進数でなければならない｡読込まれ､整数値が変数の中に保存され､寸法の修正子の値による要求に従って切詰められる｡ It is read in and the integer value is stored in the variable, truncated as required by the size modifier value.

o
  入力部分文字列は八進数でなければならない｡読込まれ､整数値が変数の中に保存され､寸法の修正子の値による要求に従って切詰められる｡ The input substring must be an octal integer. It is read in and the integer value is stored in the variable, truncated as required by the size modifier value.

x or X
  入力部分文字列は十六進数でなければならない｡読込まれ､整数値が変数の中に保存され､寸法の修正子の値による要求に従って切詰められる｡ The input substring must be a hexadecimal integer. It is read in and the integer value is stored in the variable, truncated as required by the size modifier value.

b
  入力部分文字列は二進整数でなければならない｡それは読込まれ､整数が変数に保存され､寸法修飾値によって要求された様に切詰められる｡ The input substring must be a binary integer. It is read in and the integer value is stored in the variable, truncated as required by the size modifier value.

u
  入力部分文字列は十進数でなければならない｡整数値は寸法の修正子の値による要求に従って切詰められ､相当する符号なし値が切詰められる幅に計算され十進数文字列として変数に保存される｡ The input substring must be a decimal integer. The integer value is truncated as required by the size modifier value, and the corresponding unsigned value for that truncated range is computed and stored in the variable as a decimal string.

i
  入力部分文字列は十進数でなければならない｡基底(即ち､十進､八進､十六進)は C 変換によって定められる(先頭が 0 なら八進; 0xが前置なら十六進)｡整数は変数内に保存され､寸法規制子値による要求に従って切詰められる｡　　 The input substring must be an integer. The base (i.e. decimal, octal, or hexadecimal) is determined by the C convention (leading 0 for octal; prefix 0x for hexadecimal). The integer value is stored in the variable, truncated as required by the size modifier value.

c
  一つの文字が読込まれそのユニコード値が整数として変数に保存される｡先頭の空白はこの場合には飛越されない､なので､部分文字列が空白になるかもしれない｡ A single character is read in and its Unicode value is stored in the variable as an integer value. Initial white space is not skipped in this case, so the input substring may be a white-space character.

s
  入力部分文字列は次の空白に至るまでの全ての文字を構成する､その文字は変数に複写される｡ The input substring consists of all the characters up to the next white-space character; the characters are copied to the variable.

e or f or g or E or G
  入力部分文字列は浮動小数で､任意附加的な符号､小数点を含むかもしれない十進数文字列､任意附加的な冪数で e か E に任意附加的な符号と十進数の文字列､とから構成されなければならない｡それは読み込まれ､浮動小数値として変数に保存される｡ The input substring must be a floating-point number consisting of an optional sign, a string of decimal digits possibly containing a decimal point, and an optional exponent consisting of an e or E followed by an optional sign and a string of decimal digits. It is read in and stored in the variable as a floating-point value.

[chars]
  入力部分文字列は一つ或はそれ以上の chars の中の文字から構成される｡合致した文字列が変数に保存される｡もし､角括弧の間の最初の文字が ] なら､括弧の組の終りの記号ではなくchars の一部として扱う｡もし､ chars が a-b の形式の並びに含まれるなら､なんであれ a と b の間( a と b 含む)の文字が合致する｡もし､角括弧の間の初めか終わりの文字が - なら､それは範囲を指し示しているのではなく､chars の一部として扱う｡ The input substring consists of one or more characters in chars. The matching string is stored in the variable. If the first character between the brackets is a ] then it is treated as part of chars rather than the closing bracket for the set. If chars contains a sequence of the form a-b then any character between a and b (inclusive) will match. If the first or last character between the brackets is a -, then it is treated as part of chars rather than indicating a range.

[^chars]
  入力部分文字列は一つ或はそれ以上の､ chars 以外の文字から構成される｡合致した文字列が変数に保存される｡もし､ ^ の直後に続けられている文字が ] であればそれは､括弧の終りの記号ではなくchars の一部として扱う｡もし､ chars が a-b の形式の並びに含まれるなら､なんであれ a と b の間( a と b 含む)の文字は合致の組から除かれる｡もし､角括弧の間の初めか終わりの文字が - なら､それは範囲を指し示しているのではなく､chars の一部として扱う｡ The input substring consists of one or more characters not in chars. The matching string is stored in the variable. If the character immediately following the ^ is a ] then it is treated as part of the set rather than the closing bracket for the set. If chars contains a sequence of the form a-b then any character between a and b (inclusive) will be excluded from the set. If the first or last character between the brackets is a -, then it is treated as part of chars rather than indicating a range value.

n
  入力文字列から入力は消費されない｡代りに､入力文字列から其処まで掃引された総数が変数に保存される｡ No input is consumed from the input string. Instead, the total number of characters scanned from the input string so far is stored in the variable.

変換の為に入力から読んだ文字の数はその特定の変換が意味を成す最大の数である(譬えば､%d に対して､可能な限りの十進数､ %o に対して可能な限りの八進数､以下同様)｡与えられた変換の為の入力部分文字列は､空白に遭遇するか､又は最大部分文字列幅に至るか､何れか早く来た方で終了する｡もし､変換指示子の中に * が存在すると､どの変数にも代入されず､又､次の掃引引数は消費されない｡ The number of characters read from the input for a conversion is the largest number that makes sense for that particular conversion (e.g. as many decimal digits as possible for %d, as many octal digits as possible for %o, and so on). The input substring for a given conversion terminates either when a white-space character is encountered or when the maximum substring width has been reached, whichever comes first. If a * is present in the conversion specifier then no variable is assigned and the next scan argument is not consumed.

### ANSI SSCANF との違い 　DIFFERENCES FROM ANSI SSCANF

scan 命令の振舞いは次の違いを除いて ANSI C sscanf 手続函数と同じ振舞いである: The behavior of the scan command is the same as the behavior of the ANSI C sscanf procedure except for the following differences:

1. %p 変換は運営されていない｡ %p conversion specifier is not supported.

2. %c 変換では､一つの文字の値が十進数文字列に変換され､それが対応する varName に代入される; この変換の為に部分文字列の幅は指定されない｡ For %c conversions a single character value is converted to a decimal string, which is then assigned to the corresponding varName; no substring width may be specified for this conversion.

3. h 変換は常に無視され､実数の変換の時は､ l と L 寸法の修正子は無視される(即ち､内部表現では double 型が使用される)｡ ll 寸法の修正子は sscanf に対応するものがない｡ The h modifier is always ignored and the l and L modifiers are ignored when converting real values (i.e. type double is used for the internal representation). The ll modifier has no sscanf counterpart.

4. もし､何かの変換が完了する前に､入力文字列が末尾に到達し､且つ変数が与えられてないと､空文字列が返される｡ If the end of the input string is reached before any conversions have been performed and no variables are given, an empty string is returned.

### 用例 EXAMPLES

ユニコード文字を数値に変換する: Convert a UNICODE character to its numeric value:

    set char "x"
    set value [scan $char %c]

単純な色指定の形式 #RRGGBB を部分文字列の寸法を伴った十六進数変換を使って分解する: Parse a simple color specification of the form #RRGGBB using hexadecimal conversions with substring sizes:

    set string "#08D03F"
    scan $string "#%2x%2x%2x" r g b

時間文字列 HH:MM を分解する｡ Parse a HH:MM time string:

    set string "08:08"
    if {[scan $string "%d:%d" hours minutes] != 2} {
        error "not a valid time string"
    }
    #  数の範囲を自分で心得ておく必要がある...
    # We have to understand numeric ranges ourselves...
    if {$minutes < 0 || $minutes > 59} {
        error "invalid number of minutes"
    }

文字列を非空白文字の並びに分割する(正しく先頭の空白を飛越し得るように､ %n 変換の使用に註意されたい) :　　 Break a string up into sequences of non-whitespace characters (note the use of the %n conversion so that we get skipping over leading whitespace correct):

    set string " a string {with braced words} + leading space "
    set words {}
    while {[scan $string %s%n word length] == 2} {
        lappend words $word
        set string [string range $string $length end]
    }

簡単な座標表示の文字列を分解し､末尾の文字を明示的に捜して､形式の完全性を確認する: 　　 Parse a simple coordinate string, checking that it is complete by looking for the terminating character explicitly:

    set string "(5.2,-4e-2)"
    # 掃引模様の文字部に先立つ空白は意味を有す
    # 又､")" は
    # ユニコード文字の\u0029である
    # Note that the spaces before the literal parts of
    # the scan pattern are significant, and that ")" is
    # the Unicode character \u0029
    if {
        [scan $string " (%f ,%f %c" x y last] != 3
        || $last != 0x0029
    } then {
        error "invalid coordinate string"
    }
    puts "X=$x, Y=$y"

対話的な実証として､寸法の修正子により定められた整数値の切詰め､を例示す｡ An interactive session demonstrating the truncation of integer values determined by size modifiers:

    % scan 20000000000000000000 %d
    2147483647
    % scan 20000000000000000000 %ld
    9223372036854775807
    % scan 20000000000000000000 %lld
    20000000000000000000

### SEE ALSO

format, sscanf

### KEYWORDS

conversion specifier, parse, scan
Copyright © 1993 The Regents of the University of California.
Copyright © 1994-1996 Sun Microsystems, Inc.
Copyright © 2000 Scriptics Corporation.