## Tcl9.0.3/Tk9.0.3 Documentation > Tcl Commands > subst

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

### NAME

subst — 逆斜線置換と命令置換と変数置換を遂行する Perform backslash, command, and variable substitutions

### 構文 SYNOPSIS

subst ?-nobackslashes? ?-nocommands? ?-novariables? string

### 説明 DESCRIPTION

この命令は､その string 引数に､変数置換と､命令置換と､逆斜線置換を遂行し､全て置換した結果を返す｡置換は Tcl 命令用と厳密に同じ方法で遂行される｡結果として､ string 引数は実際に２回置換される､一度は Tcl 命令の為の通常の方式のTcl構文解析により､次に再び､ subst 命令によって為される｡ 　 This command performs variable substitutions, command substitutions, and backslash substitutions on its string argument and returns the fully-substituted result. The substitutions are performed in exactly the same way as for Tcl commands. As a result, the string argument is actually substituted twice, once by the Tcl parser in the usual fashion for Tcl commands, and again by the subst command.

もし､ -nobackslashes か -nocommands か -novariables のどれかが指定されると､対応する置換は遂行されない｡譬えば､もし -nocommands が指定されると､命令置換は遂行されない: 左角括弧と右角括弧は通常の文字として特別な解釈はされない｡ 　 If any of the -nobackslashes, -nocommands, or -novariables are specified, then the corresponding substitutions are not performed. For example, if -nocommands is specified, command substitution is not performed: open and close brackets are treated as ordinary characters with no special interpretation.

注意すべきは､一つの種類の置換が他の種類の置換を含むこともあり得る｡譬えば､縦え -novariables 指示項目が指定されていても､命令置換は制限を受けずに遂行される｡この意味は､命令置換を完成させる為に必要なら､どの様な変数置換も､そのまま行われる｡同様に､変数置換を完成させる為に必要なら､どの様な命令置換も､縦え -nocommands が指定されていても､行われる｡下の EXAMPLES を参照されたい｡ 　 Note that the substitution of one kind can include substitution of other kinds. For example, even when the -novariables option is specified, command substitution is performed without restriction. This means that any variable substitution necessary to complete the command substitution will still take place. Likewise, any command substitution necessary to complete a variable substitution will take place, even when -nocommands is specified. See the EXAMPLES below.

もし､置換の間に不都合が生じると､ subst はその不都合を返す｡もし､命令又は変数置換の間に break 例外が生じると､全体の置換の結果は､例外を起こした置換の始りまでの(置換された通りの)文字列になる｡もし､continue 例外が命令又は変数置換の間に生じると､空文字列が全体の命令又は変数置換の為の置換になる(適正なTcl形式になっている限り)｡もし､return 例外が起るか､又は､何か他の return code が命令か変数置換の間に返されると返り値はその置換に置換えられる｡下の EXAMPLES を参照されたい｡この方法では､全ての例外返り codes は subst に “捕捉” される｡ subst 命令そのものは不都合を返すか､成功裡に完了する｡ 　 If an error occurs during substitution, then subst will return that error. If a break exception occurs during command or variable substitution, the result of the whole substitution will be the string (as substituted) up to the start of the substitution that raised the exception. If a continue exception occurs during the evaluation of a command or variable substitution, an empty string will be substituted for that entire command or variable substitution (as long as it is well-formed Tcl.) If a return exception occurs, or any other return code is returned during command or variable substitution, then the returned value is substituted for that substitution. See the EXAMPLES below. In this way, all exceptional return codes are “caught” by subst. The subst command itself will either return an error, or will complete successfully.

### 用例 EXAMPLES

subst は､その置換を遂行する時に､二重引用や波括弧に(命令置換の内部を除いて)どの様な特別な扱いも与えないので､次の記述譜は 　 When it performs its substitutions, subst does not give any special treatment to double quotes or curly braces (except within command substitutions) so the script

    set a 44
    subst {xyz {$a}}

“xyz {44}” を返し､ “xyz {$a}” ではない､又記述譜の 　 　 returns “xyz {44}”, not “xyz {$a}” and the script

    set a "p\} q \{r"
    subst {xyz {$a}}

は “xyz {p} q {r}” を返し､ “xyz {p\} q \{r}” ではない｡ 　 returns “xyz {p} q {r}”, not “xyz {p\} q \{r}”.

命令置換が遂行される時は､記述譜を評価する為に必要などの様な変数置換も含む｡ 　 When command substitution is performed, it includes any variable substitution necessary to evaluate the script.

    set a 44
    subst -novariables {$a [format $a]}

“$a 44” を返す､ “$a $a” ではない｡同様に､変数置換が遂行される時は､変数の値を取出す為に必要な､どの様な命令置換も含む｡ 　 returns “$a 44”, not “$a $a”. Similarly, when variable substitution is performed, it includes any command substitution necessary to retrieve the value of the variable.

    proc b {} {return c}
    array set a {c c [b] tricky}
    subst -nocommands {[b] $a([b])}

“[b] c” を返す､ “[b] tricky” ではない｡ 　 returns “[b] c”, not “[b] tricky”.

continue 例外と break 例外は､命令置換に残りの命令置換と残りの string のそれぞれの置換の阻止を許容し､記述譜の著者に subst を使用して文章を処理する時に更なる選択を与える｡譬えば､次の記述譜は 　 The continue and break exceptions allow command substitutions to prevent substitution of the rest of the command substitution and the rest of string respectively, giving script authors more options when processing text using subst. For example, the script

    subst {abc,[break],def}

は “abc,” を返す､ “abc,,def” ではない､又､記述譜は 　 returns “abc,”, not “abc,,def” and the script

    subst {abc,[continue;expr {1+2}],def}

は “abc,,def” を返す､ “abc,3,def” ではない｡ 　 　 returns “abc,,def”, not “abc,3,def”.

他の例外のreturn codes は返される値を置換する 　 Other exceptional return codes substitute the returned value

    subst {abc,[return foo;expr {1+2}],def}

は “abc,foo,def” を返す､ “abc,3,def” ではない､又 　 　 returns “abc,foo,def”, not “abc,3,def” and

    subst {abc,[return -code 10 foo;expr {1+2}],def}

は “abc,foo,def” を返す､ “abc,3,def” ではない｡ 　 also returns “abc,foo,def”, not “abc,3,def”.

### SEE ALSO

Tcl, eval, break, continue

### KEYWORDS

backslash substitution, command substitution, quoting, substitution, variable substitution
Copyright © 1994 The Regents of the University of California.
Copyright © 1994-1996 Sun Microsystems, Inc.
Copyright © 2001 Donal K. Fellows