## Tcl9.0.3/Tk9.0.3 Documentation > Tcl Commands > lsort

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

  NAME
    lsort — リストの要素を順に並び揃える Sort the elements of a list
  構文 SYNOPSIS
  説明 DESCRIPTION
    -ascii
    -dictionary
    -integer
    -real
    -command command
    -increasing
    -decreasing
    -indices
    -index indexList
    -stride strideLength
    -nocase
    -unique
  註意 NOTES
  用例 EXAMPLES
  SEE ALSO
  KEYWORDS

### NAME

lsort — リストの要素を順に並び揃える Sort the elements of a list

### 構文 SYNOPSIS

lsort ?options? list

### 説明 DESCRIPTION

この命令はリスト list の要素を大きさ順に並び揃え､並び揃えた新しいリストを返す｡この lsort 命令の実装には､所要時間特性が O(n log n) を達成できる安定な併合揃え法を使用している｡ 　　　　 This command sorts the elements of list, returning a new list in sorted order. The implementation of the lsort command uses the merge-sort algorithm which is a stable sort that has O(n log n) performance characteristics.

省略時設定では ASCII 揃えが使われ､漸増順の結果が返される｡但し､揃える方法を制御する為に list の前に､次のどれかの指示項目を置くことができる(他と綴りが重複しない短縮表記も受入れられる): 　　　　 By default ASCII sorting is used with the result returned in increasing order. However, any of the following options may be specified before list to control the sorting process (unique abbreviations are accepted):

-ascii
  ユニコードの符号照合の順序による文字列比較を使う(旧版との互換性を保つ為にこの名称を使用している)｡この比較法が省略時設定である｡ 　　　　 Use string comparison with Unicode code-point collation order (the name is for backward-compatibility reasons.) This is the default.

-dictionary
  辞書式の比較を使う｡ -ascii と同じ様だが､違いは (a) 綴りが同一になる場合を除き､大文字と小文字の区別は無視される､ (b) もし､二つの文字列が埋込まれた数字を含む場合､その数字は文字列としてではなく､整数値として順序比較する｡譬えば -dictionary 様式では､ bigBoy は bigbang と bigboy の間の順位に入り､又､ x10y は x9y と x11y の間の順位に入る｡-nocase 指定を上書きする｡　　　 Use dictionary-style comparison. This is the same as -ascii except (a) case is ignored except as a tie-breaker and (b) if two strings contain embedded numbers, the numbers compare as integers, not characters. For example, in -dictionary mode, bigBoy sorts between bigbang and bigboy, and x10y sorts between x9y and x11y. Overrides the -nocase option.

-integer
  リストの要素を整数に変換し､整数値比較を使う｡ 　　　　 Convert list elements to integers and use integer comparison.

-real
  リストの要素を整数に変換し､整数値比較を使う｡ 　　　　 Convert list elements to floating-point values and use floating comparison.

-command command
  比較命令として command を使う｡二つの要素を比較する為に､二つの要素を引数として後ろに従えて構成した command と謂う Tcl 記述譜を評価する｡その記述譜は､第一の要素が､第二要素よりも､小さいか､等しいか､大きいかに対応して､零より小さい､等しい､大きい整数を返すようにしておく｡ 　　　　 Use command as a comparison command. To compare two elements, evaluate a Tcl script consisting of command with the two elements appended as additional arguments. The script should return an integer less than, equal to, or greater than zero if the first element is to be considered less than, equal to, or greater than the second, respectively.

-increasing
  リストを漸増する順に並べる (“最小”の品目が最初になる) ｡この方向が､省略時設定でもある｡ 　　　　Sort the list in increasing order (“smallest”items first). This is the default.

-decreasing
  リストを漸減する順に並べる｡ (“最大”の品目が最初に来る) ｡ 　　Sort the list in decreasing order (“largest”items first).

-indices
  値そのものの代りに整列したリストの元の順番をリストの中に入れて返す｡ 　　　　 Return a list of indices into list in sorted order instead of the values themselves.

-index indexList
  この指示項目が指定される時は(-stride が使われない限り) リスト list の各要素も Tcl の文法に適った小リストになっていなければならない｡lsort は､小リスト全体に基づいて揃えるのではなく､それぞれの小リストから indexList 番目の要素を取出し(恰も､全ての要素と indexList が lindex に渡されたかのように)､与えられた要素に基いて並び揃える｡譬えば､ 　　　 If this option is specified, each of the elements of list must itself be a proper Tcl sublist (unless -stride is used). Instead of sorting based on whole sublists, lsort will extract the indexList'th element from each sublist (as if the overall element and the indexList were passed to lindex) and sort based on the given element. For example,

      lsort -integer -index 1 \
            {{First 24} {Second 18} {Third 30}}

  は {Second 18} {First 24} {Third 30} を返す､そして 　　　　 returns {Second 18} {First 24} {Third 30},

      lsort -index end-1 \
              {{a 1 e i} {b 2 3 f g} {c 4 5 6 d h}}

  は {c 4 5 6 d h} {a 1 e i} {b 2 3 f g} を返す､そして 　　　　 returns {c 4 5 6 d h} {a 1 e i} {b 2 3 f g}, and

      lsort -index {0 1} {
          {{b i g} 12345}
          {{d e m o} 34512}
          {{c o d e} 54321}
      }

  は {{d e m o} 34512} {{b i g} 12345} {{c o d e} 54321} を返す(理由は e は i より早く､次に o が来る｡) この指示項目を使用すると､同じ効果を得るにも -command 指示項目よりも充分効率的である｡ 　　　　 returns {{d e m o} 34512} {{b i g} 12345} {{c o d e} 54321} (because e sorts before i which sorts before o.) This option is much more efficient than using -command to achieve the same effect.

-stride strideLength
  この指示項目が指定されると､リストは strideLength 個の要素の群から構成されるとして扱われ､それらの群はその最初の要素によって､もしくは､ -index 指定が使われるとそれぞれの群の中から､始めに -index に渡される索引番号によって与えられる要素(それは -index 指定に無視される)によって揃えられる｡要素は常に群内の同じ位置に留まる 　　　　 If this option is specified, the list is treated as consisting of groups of strideLength elements and the groups are sorted by either their first element or, if the -index option is used, by the element within each group given by the first index passed to -index (which is then ignored by -index). Elements always remain in the same position within their group.

  リスト長さは strideLength の整数倍でなければならず､更にはその長さは最小限2でなければならない｡ 　　　　 The list length must be an integer multiple of strideLength, which in turn must be at least 2.

  譬えば､ 　　　　 For example,

      lsort -stride 2 {carrot 10 apple 50 banana 25}

  は “apple 50 banana 25 carrot 10” を返し､又 　　　　　 returns “apple 50 banana 25 carrot 10”, and

      lsort -stride 2 -index 1 -integer {carrot 10 apple 50 banana 25}

  は “carrot 10 banana 25 apple 50” を返す｡ 　　　　　　 returns “carrot 10 banana 25 apple 50”.

-nocase
  大文字小文字の区別なしの様式で扱われる比較を惹き起こす｡この指示項目は -dictionary や -integer や -real 指示項目と組合せて使用しても特段の効果はない｡ 　　　　 Causes comparisons to be handled in a case-insensitive manner. Has no effect if combined with the -dictionary, -integer, or -real options.

-unique
  もしこの指示項目が指定されると､リスト中で見出される重複した要素の最後の組だけが残される｡註意 重複の判定は順序付けに使われる比較方法に依存する｡もしも､ -index 0 が指定されると {1 a} と {1 b} は重複していると看做され､第二要素の {1 b} だけが保持される｡ 　　　　 If this option is specified, then only the last set of duplicate elements found in the list will be retained. Note that duplicates are determined relative to the comparison used in the sort. Thus if -index 0 is used, {1 a} and {1 b} would be considered duplicates and only the second element, {1 b}, would be retained.

### 註意 NOTES

lsort の指示項目は順序付けにどのような種類の比較方法が使われるかを制御するだけであり､値そのものがどのようなものかで必要になる制約ではない｡このことは順序付けすべきリストの要素が二つよりも少ない時に際立つ特徴である｡[訳註 要素１個なら指示項目に何を付けても結果は同じ] 　　　　 The options to lsort only control what sort of comparison is used, and do not necessarily constrain what the values themselves actually are. This distinction is only noticeable when the list to be sorted has fewer than two elements.

この lsort 命令は再起呼出し可能である､即ち -command 指示項目の中で使われる命令の中で実装の一部として安全に使用できる｡ 　　　　 The lsort command is reentrant, meaning it is safe to use as part of the implementation of a command used in the -command option.

### 用例 EXAMPLES

リストを ASCII 法で整列する: 　　　　 Sorting a list using ASCII sorting:

    % lsort {a10 B2 b1 a1 a2}
    B2 a1 a10 a2 b1

リストを dictionary 法で整列する: 　　　　 Sorting a list using Dictionary sorting:

    % lsort -dictionary {a10 B2 b1 a1 a2}
    a1 a2 a10 b1 B2

整数のリストを整列する: 　　　　 Sorting lists of integers:

    % lsort -integer {5 3 1 2 11 4}
    1 2 3 4 5 11
    % lsort -integer {1 2 0x5 7 0 4 -1}
    -1 0 1 2 4 0x5 7

浮動少数のリストを整列する: 　　　　 Sorting lists of floating-point numbers:

    % lsort -real {5 3 1 2 11 4}
    1 2 3 4 5 11
    % lsort -real {.5 0.07e1 0.4 6e-1}
    0.4 .5 6e-1 0.07e1

index 法でリストを整列する: 　　　　 Sorting using indices:

    % # Note the space character before the c
    % lsort {{a 5} { c 3} {b 4} {e 1} {d 2}}
    { c 3} {a 5} {b 4} {d 2} {e 1}
    % lsort -index 0 {{a 5} { c 3} {b 4} {e 1} {d 2}}
    {a 5} {b 4} { c 3} {d 2} {e 1}
    % lsort -index 1 {{a 5} { c 3} {b 4} {e 1} {d 2}}
    {e 1} {d 2} { c 3} {b 4} {a 5}

辞書を揃える: 　　　　 Sorting a dictionary:

    % set d [dict create c d a b h i f g c e]
    c e a b h i f g
    % lsort -stride 2 $d
    a b c e f g h i

群分けと多重索引を使って揃える: 　　　　 Sorting using striding and multiple indices:

    % # Note the first index value is relative to the group
    % lsort -stride 3 -index {0 1} \
         {{Bob Smith} 25 Audi {Jane Doe} 40 Ford}
    {{Jane Doe} 40 Ford {Bob Smith} 25 Audi}

整列法を使って重複を削除する: 　　　　 Stripping duplicate values using sorting:

    % lsort -unique {a b c a b c a b c}
    a b c

比較用の函数を使った高度な整列法: 　　　　 More complex sorting using a comparison function:

    % proc compare {a b} {
        set a0 [lindex $a 0]
        set b0 [lindex $b 0]
        if {$a0 < $b0} {
            return -1
        } elseif {$a0 > $b0} {
            return 1
        }
        return [string compare [lindex $a 1] [lindex $b 1]]
    }
    % lsort -command compare \
            {{3 apple} {0x2 carrot} {1 dingo} {2 banana}}
    {1 dingo} {2 banana} {0x2 carrot} {3 apple}

### SEE ALSO

list, lappend, lassign, ledit, lindex, linsert, llength, lmap, lpop, lrange, lremove, lrepeat, lreplace, lreverse, lsearch, lseq, lset

### KEYWORDS

element, list, order, sort
Copyright © 1993 The Regents of the University of California.
Copyright © 1994-1996 Sun Microsystems, Inc.
Copyright © 1999 Scriptics Corporation
Copyright © 2001 Kevin B. Kenny <kennykb(at)acm.org>. All rights reserved.