## Tcl8.6.17/Tk8.6.17 Documentation > Tcl Commands > apply

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

### NAME

apply — その場限りの名前の函数を適用する Apply an anonymous function

### 構文 SYNOPSIS

apply func ?arg1 arg2 ...?

### 説明 DESCRIPTION

この apply 命令は引数 arg1 arg2 ... に函数 func を適用し結果を返す｡ The command apply applies the function func to the arguments arg1 arg2 ... and returns the result.

函数 func は(恰も list 命令が使われたかの如く)要素２つのリスト {引数 本体} 又は 要素３つのリスト {引数 本体 名前空間} である｡第一要素の引数 args は 函数 func に対する形式上の引数を指定する｡形式上の引数 args の詳細事項は proc 命令と共有することになる､その詳細は取扱説明書の該当する頁に記載されている｡ The function func is a two element list {args body} or a three element list {args body namespace} (as if the list command had been used). The first element args specifies the formal arguments to func. The specification of the formal arguments args is shared with the proc command, and is described in detail in the corresponding manual page.

本体 の中身は形式上の引数に該当する局所変数に実際の假引数 arg1 arg2 .... の値が与えられた後に Tcl 解釈実行機能で実行される｡本体 body が実行される時､変数名は通常局所変数を参照し､その変数は､参照時に自動的に生成され､apply が戻る時に消滅される｡函数のそれぞれの引数毎に一個の局所変数が自動的に生成される｡大域変数は global 命令又は upvar 命令が起動した時のみ､利用され得る｡名前空間変数は､variable 命令又は upvar 命令が起動したときのみ利用され得る｡ The contents of body are executed by the Tcl interpreter after the local variables corresponding to the formal arguments are given the values of the actual parameters arg1 arg2 .... When body is being executed, variable names normally refer to local variables, which are created automatically when referenced and deleted when apply returns. One local variable is automatically created for each of the function's arguments. Global variables can only be accessed by invoking the global command or the upvar command. Namespace variables can only be accessed by invoking the variable command or the upvar command.

apply の起動によりTclの評価実行スタックに呼出し枠組みが付加される(その枠組みのスタックは uplevel 経由で利用される)｡本体 body の実行はこの呼び出し枠組み中で､ 名前空間 namespace として与えられた名前空間の中､或いは名前空間が指定されてない時は大域変名前空間の中で､進行する｡もし､名前空間 namespace が与えられると､その名前が “::” で始まっていなくとも､大域名前空間に関して相対的に名前空間が解釈される｡ The invocation of apply adds a call frame to Tcl's evaluation stack (the stack of frames accessed via uplevel). The execution of body proceeds in this call frame, in the namespace given by namespace or in the global namespace if none was specified. If given, namespace is interpreted relative to the global namespace even if its name does not start with “::”.

apply の擬似的な仕組みは次のように記述できる: The semantics of apply can also be described by:

    proc apply {fun args} {
        set len [llength $fun]
        if {($len < 2) || ($len > 3)} {
             error "can't interpret \"$fun\" as anonymous function"
        }
        lassign $fun argList body ns
        set name ::$ns::[getGloballyUniqueName]
        set body0 {
             rename [lindex [info level 0] 0] {}
        }
        proc $name $argList ${body0}$body
        set code [catch {uplevel 1 $name $args} res opt]
        return -options $opt $res
    }

### 用例 EXAMPLES

この例では､リストの各要素に変換を適用する為の､簡単で一般的な命令の作り方を示した｡[訳註 lmap 命令の疑似命令､但し引数の順序は違う] This shows how to make a simple general command that applies a transformation to each element of a list.

    proc map {lambda list} {
        set result {}
        foreach item $list {
            lappend result [apply $lambda $item]
        }
        return $result
    }
    map {x {return [string length $x]:$x}} {a bb ccc dddd}
          → 1:a 2:bb 3:ccc 4:dddd
    map {x {expr {$x**2 + 3*$x - 2}}} {-4 -3 -2 -1 0 1 2 3 4}
          → 2 -2 -4 -4 -2 2 8 16 26

この apply 命令は trace 命令の中での呼出しの指定にも有用である: The apply command is also useful for defining callbacks for use in the trace command:

    set vbl "123abc"
    trace add variable vbl write {apply {{v1 v2 op} {
        upvar 1 $v1 v
        puts "updated variable to \"$v\""
    }}}
    set vbl 123
    set vbl abc

### SEE ALSO

proc, uplevel

### KEYWORDS

anonymous function, argument, lambda, procedure
Copyright © 2006 Miguel Sofer
Copyright © 2006 Donal K. Fellows