## Tcl8.6.17/Tk8.6.17 Documentation > Tcl Commands > switch

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

  NAME
    switch — 与えられた値に従って､幾つかの記述譜の内の一つを評価する｡　 Evaluate one of several scripts, depending on a given value
  構文 SYNOPSIS
  説明 DESCRIPTION
    -exact
    -glob
    -regexp
    -nocase
    -matchvar varName
    -indexvar varName
    --
  用例 EXAMPLES
  SEE ALSO
  KEYWORDS

### NAME

switch — 与えられた値に従って､幾つかの記述譜の内の一つを評価する｡　 Evaluate one of several scripts, depending on a given value

### 構文 SYNOPSIS

switch ?options? string pattern body ?pattern body ...?

switch ?options? string {pattern body ?pattern body ...?}

### 説明 DESCRIPTION

switch 命令は､その 文字列 引数を､それぞれの 紋様 引数に順番に引合わせる｡ 文字列 に合致する紋様 が見つかるとただちに､その直後の 本体 引数を再帰的にTcl 解釈実行機能に引き渡して評価し､その評価結果を返す｡もし､最後の紋様 引数が default であった場合は何にでも合致する｡もしどの紋様 引数も文字列に合致せず､且つ､default が与えられない場合､switch 命令は空文字列を返す｡ The switch command matches its string argument against each of the pattern arguments in order. As soon as it finds a pattern that matches string it evaluates the following body argument by passing it recursively to the Tcl interpreter and returns the result of that evaluation. If the last pattern argument is default then it matches anything. If no pattern argument matches string and no default is given, then the switch command returns an empty string.

もし､switch の最初の引数が - で始まっていたら､switch に対する引数の個数が厳密に二個である場合(その場合､第１引数は文字列 でなければならず､且つ､第２引数は紋様/本体 のリストでなければならない)以外は､選択子であると看做される｡次の選択子が用意されている: If the initial arguments to switch start with - then they are treated as options unless there are exactly two arguments to switch (in which case the first must the string and the second must be the pattern/body list). The following options are currently supported:

-exact
  文字列を紋様に比較する時に､厳密合致を使用する｡これは､省略時設定でもある｡ Use exact matching when comparing string to a pattern. This is the default.

-glob
  文字列を紋様に比較する時に､文字列展開形式の合致比較(即ち､string match 命令に実装されたものと同じ)を使う｡ When matching string to the patterns, use glob-style matching (i.e. the same as implemented by the string match command).

-regexp
  文字列を紋様に比較する時に､正規表現(正規表現re_syntax参照頁に記載された様に)を使う｡ When matching string to the patterns, use regular expression matching (as described in the re_syntax reference page).

-nocase
  大文字小文字を区別しない方法で比較する｡ Causes comparisons to be handled in a case-insensitive manner.

-matchvar varName
  この指定は(-regexp も同時に指定されている場合にのみ有効)正規表現の機能譜によって合致することが判ったリストが書き込まれる変数の名前を指定する｡書込まれるリストの最初の要素は､入力文字列(即ち､switch の文字列引数)の内の､合致した全体の文字列であり､リストの第２の要素は､正規表現の内の､最初の括り出し括弧に合致した文字列であり､以下同様に続いていく｡ default に分岐した時は､この変数に空文字列が入る｡この指定は -indexvar 指定と同時に指定できる｡ This option (only legal when -regexp is also specified) specifies the name of a variable into which the list of matches found by the regular expression engine will be written. The first element of the list written will be the overall substring of the input string (i.e. the string argument to switch) matched, the second element of the list will be the substring matched by the first capturing parenthesis in the regular expression that matched, and so on. When a default branch is taken, the variable will have the empty list written to it. This option may be specified at the same time as the -indexvar option.

-indexvar varName
  この選択子は( -regexp も同時に指定されている場合にのみ有効)正規表現の機能譜によって判った､合致の部分文字列を参照する文字位置のリストが書き込まれる変数の名前を指定する｡書込まれるリストの最初の要素は､入力文字列(即ち､switch の文字列引数)の内の､合致した全体の文字列の最初と最後の位置の２要素のリストであり､即ち､ regexp に対して -indices 選択子で得られる方法と似ている｡同様にして､リストの第２要素は､正規表現が合致する最初の括り出し括弧の合致を参照するリストであり､以下同様である｡ default に分岐した時は､この変数に空文字列が入る｡この選択子は -matchvar 選択子と同時に指定できる｡ This option (only legal when -regexp is also specified) specifies the name of a variable into which the list of indices referring to matching substrings found by the regular expression engine will be written. The first element of the list written will be a two-element list specifying the index of the start and index of the first character after the end of the overall substring of the input string (i.e. the string argument to switch) matched, in a similar way to the -indices option to the regexp can obtain. Similarly, the second element of the list refers to the first capturing parenthesis in the regular expression that matched, and so on. When a default branch is taken, the variable will have the empty list written to it. This option may be specified at the same time as the -matchvar option.

--
  選択子の終わりを示す｡この後に続く引数は､縦え - で始まる場合でも､文字列として扱われる｡ 一致する紋様と本体が単一の引数にまとめられたときには､必須ではない｡ Marks the end of options. The argument following this one will be treated as string even if it starts with a -. This is not required when the matching patterns and bodies are grouped together in a single argument.

紋様と本体の引数に対して､二つの構文が用意されている｡第１のものは､それぞれの紋様と命令に対して別々の引数を使う；この形式は､どれかの紋様や命令に置換が必要な時に便利である｡第２の形式は､全ての紋様と命令を単一の引数に統合する；その引数は､紋様と命令の要素からなる､適切なリスト形式であることを要する｡二番目の形式は､リスト全体を波括弧で囲むので､各行末尾毎に逆斜線を含めることが不要となるので､複数行の切替命令に便利である｡第二の形式では紋様の引数が波括弧の内にあるので､命令や変数に対して置換が行われない；このことは､ある場合に､第二の形式の振舞いに､第一の形式との違いをもたらすことになる｡ Two syntaxes are provided for the pattern and body arguments. The first uses a separate argument for each of the patterns and commands; this form is convenient if substitutions are desired on some of the patterns or commands. The second form places all of the patterns and commands together into a single argument; the argument must have proper list structure, with the elements of the list being the patterns and commands. The second form makes it easy to construct multi-line switch commands, since the braces around the whole list make it unnecessary to include a backslash at the end of each line. Since the pattern arguments are in braces in the second form, no command or variable substitutions are performed on them; this makes the behavior of the second form different than the first form in some cases.

本体に “-” が指定されていると､次の紋様に対する本体を､ここの本体として使うことを意味する(次の紋様も “-” の本体を有するときは､その後ろの本体が使用され､更に同様に繰り返す)｡この性質により､幾つかの紋様の間で単一の本体を共有することが可能になる｡ If a body is specified as “-” it means that the body for the next pattern should also be used as the body for this pattern (if the next pattern also has a body of “-” then the body after that is used, and so on). This feature makes it possible to share a single body among several patterns.

switch 命令に注釈をいかに置くかは慎重にされたい｡注釈は､紋様の内の一つの実行用本体内部にのみ置くべきで､紋様と混在しない必要がある｡ Beware of how you place comments in switch commands. Comments should only be placed inside the execution body of one of the patterns, and not intermingled with the patterns.

### 用例 EXAMPLES

switch 命令では文字並びだけでなく､変数に対して合致させる事も可能である(この例の結果は2である): The switch command can match against variables and not just literals, as shown here (the result is 2):

    set foo "abc"
    switch abc a - b {expr {1}} $foo {expr {2}} default {expr {3}}

展開形式の合致と､落し穴式の本体(訳註 上述の ’ “-” なら 次の本体を実行’ を指す)を使うと､正規表現の代替書式による書換えになる､この様になる(この場合 1が返る): Using glob matching and the fall-through body is an alternative to writing regular expressions with alternations, as can be seen here (this returns 1):

    switch -glob aaab {
        a*b     -
        b       {expr {1}}
        a*      {expr {2}}
        default {expr {3}}
    }

何にも一致しないときは､ default 句が （最後でなければならない）が実行される｡ この例では､3の結果が返る: Whenever nothing matches, the default clause (which must be last) is taken. This example has a result of 3:

    switch xyz {
        a -
        b {
            # 注釈の正しい位置
            # Correct Comment Placement
            expr {1}
        }
        c {
            expr {2}
        }
        default {
            expr {3}
        }
    }

正規表現に対して合致した場合､ -matchvar 指定を使うと､正確に一致した情報が容易に得られる： When matching against regular expressions, information about what exactly matched is easily obtained using the -matchvar option:

    switch -regexp -matchvar foo -- $bar {
        a(b*)c {
            puts "Found [string length [lindex $foo 1]] 'b's"
        }
        d(e*)f(g*)h {
            puts "Found [string length [lindex $foo 1]] 'e's and\
                    [string length [lindex $foo 2]] 'g's"
        }
    }

### SEE ALSO

for, if, regexp

### KEYWORDS

switch, match, regular expression
Copyright © 1993 The Regents of the University of California.
Copyright © 1994-1997 Sun Microsystems, Inc.