## Tcl9.0.3/Tk9.0.3 Documentation > [incr Tcl] Package Commands, version 4.3.5 > body

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

### NAME

itcl::body — 手段/手続函数 級の為の本体を変更する 　　change the body for a class method/proc

### 構文 SYNOPSIS

itcl::body className::function args body

### 説明 DESCRIPTION

この body 命令は 級の 手段 又は 手続函数 の本体を定義又は再定義する為に [incr Tcl] 級定義の外で使用される｡この便益により級定義を "対話機能" 部分 と "実装" 部分に分離させることができる｡"対話機能" 部分は､手段と､手続函数と､即値変数と､共通変数の為の宣言を伴う 級 命令である｡"実装"部分は body 命令と configbody 命令の並びである｡もし "実装" 部分が別のファイルに保有されていると､対話的開発を運営する為に､瑕疵の修正につれ繰返し繰り返し提供することができる｡あの emacs 校正譜内で "tcl" 様式として使用する時､この "対話機能"部分 と "実装" 部分は同じファイル内に保有することができ; 瑕疵修正につれ､その箇所の本体を強調でき､試験応用譜に送ることができる｡　　　　　 The body command is used outside of an [incr Tcl] class definition to define or redefine the body of a class method or proc. This facility allows a class definition to have separate "interface" and "implementation" parts. The "interface" part is a class command with declarations for methods, procs, instance variables and common variables. The "implementation" part is a series of body and configbody commands. If the "implementation" part is kept in a separate file, it can be sourced again and again as bugs are fixed, to support interactive development. When using the "tcl" mode in the emacs editor, the "interface" and "implementation" parts can be kept in the same file; as bugs are fixed, individual bodies can be highlighted and sent to the test application.

名称"className::function"は変更されている 手段/手続函数　を識別する｡ 　　　 The name "className::function" identifies the method/proc being changed.

函数 function が級定義内で定義された時に､引数リスト args が指定された場合､body 命令の為の引数リスト args はその意味に合致しなければならない｡変数名は変わるかもしれないが､引数リストは必要な同じ引数を保持しなければならず､又､追加指定された引数に対する同じ省略時設定を保持しなければならない｡特別な引数 args は級定義内の args リストに含まれる時は､何にでも合致するように振舞う; それは､本体が再定義された時に､どのような型の､零個から多数個の引数にも合致する｡　　　　　 If an args list was specified when the function was defined in the class definition, the args list for the body command must match in meaning. Variable names can change, but the argument lists must have the same required arguments and the same default values for optional arguments. The special args argument acts as a wildcard when included in the args list in the class definition; it will match zero or more arguments of any type when the body is redefined.

もし body 文字列が "@" で始まっている場合､それは C 言語手続函数の為の記号の名称として扱われる｡その args リストは､予定された使用法を説明する以外には C 言語手続函数としては大した意味を有さない｡( C 言語手続函数はこの方法では引数の使用が保障されない｡) もし body が "@" で始まらない場合は Tcl 命令記述譜として取扱われる｡手続函数が起動された時､命令行引数は args リストに対して合致し､それぞれの引数を顕彰する局所変数が生成される｡これは､Tcl-様式の手続函数に対して便利な振舞いである｡　　　　　 If the body string starts with "@", it is treated as the symbolic name for a C procedure. The args list has little meaning for the C procedure, except to document the expected usage. (The C procedure is not guaranteed to use arguments in this manner.) If body does not start with "@", it is treated as a Tcl command script. When the function is invoked, command line arguments are matched against the args list, and local variables are created to represent each argument. This is the usual behavior for a Tcl-style proc.

C 言語手続函数についての記号名称は Itcl_RegisterObjC() 経由で手続函数の登録により確立される｡ これは通常､解釈実行機能が始動する時に自動的に呼出される Tcl_AppInit() 手続函数内で実行される｡ 次の実施例の中で手続函数 My_FooObjCmd() は記号名称 "foo" として登録される｡この手続函数は body 命令の中で "@foo" として参照することができる｡ Symbolic names for C procedures are established by registering procedures via Itcl_RegisterObjC(). This is usually done in the Tcl_AppInit() procedure, which is automatically called when the interpreter starts up. In the following example, the procedure `My_FooObjCmd()` is registered with the symbolic name "foo". This procedure can be referenced in the body command as "`@foo`".

    int
    Tcl_AppInit(interp)
        Tcl_Interp *interp;     /* Interpreter for application. */
    {
        if (Itcl_Init(interp) == TCL_ERROR) {
            return TCL_ERROR;
        }

        if (Itcl_RegisterObjC(interp, "foo", My_FooObjCmd) != TCL_OK) {
            return TCL_ERROR;
        }
    }

### 用例 EXAMPLE

次の実施例内で､ "File" 級は開いたファイルの具現を定義する｡手段の本体は body 命令経由で級の定義の下に含まれる｡註意すべきは､構築子/解体子 の本体は級内の定義に含まれなければならないが､ body 命令経由で同じように再定義できる｡　　　 In the following example, a "File" class is defined to represent open files. The method bodies are included below the class definition via the body command. Note that the bodies of the constructor/destructor must be included in the class definition, but they can be redefined via the body command as well.

    itcl::class File {
        private variable fid ""
        constructor {name access} {
            set fid [open $name $access]
        }
        destructor {
            close $fid
        }

        method get {}
        method put {line}
        method eof {}
    }

    itcl::body File::get {} {
        return [gets $fid]
    }
    itcl::body File::put {line} {
        puts $fid $line
    }
    itcl::body File::eof {} {
        return [::eof $fid]
    }

    #
    # 動作中の File 級を観察されたい:
    # See the File class in action:
    #
    File x /etc/passwd "r"
    while {![x eof]} {
        puts "=> [x get]"
    }
    itcl::delete object x

### KEYWORDS

class, object, procedure
Copyright © 1993-1998 Lucent Technologies, Inc.