## Tcl8.6.17/Tk8.6.17 Documentation > Tcl Commands > upvar

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite3 Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

### NAME

upvar — 異なる棚枠中の変数に連結を作成する Create link to variable in a different stack frame

### 構文 SYNOPSIS

upvar ?level? otherVar myVar ?otherVar myVar ...?

### 説明 DESCRIPTION

この命令は､現在の手続き函数内の一つ或は複数の局所変数の為に､内包している手続き函数呼出し内の変数や大域変数への参照を手配する｡水準 level は uplevel 命令に許容されるどの様な形式でもよく､省略もできる(省略時設定で 1 になる)｡それぞれの otherVar 引数について､ upvar は level によって与えられた手続き函数の枠組み(又はlevel が #0 の場合は大域水準)内の名前による変数を､対応するmyVar引数内で与えられた名前により現在の手続き函数内で利用可能にする｡otherVar と名付けられた変数は呼出時に実在する必要はない ; myVar は､最初に参照される時に､普通の変数と丁度同じ様に創生されることになる｡upvar が起動される時に myVar が実在していてはならない｡myVar は常に､配列ではなく､変数の名前として扱われる｡譬えば a(b) の如く､名前が配列要素の様に見えると不都合が返される｡otherVar は､単純変数や､配列や､配列要素を参照できる｡upvar は空文字列を返す｡ 　 　 This command arranges for one or more local variables in the current procedure to refer to variables in an enclosing procedure call or to global variables. Level may have any of the forms permitted for the uplevel command, and may be omitted (it defaults to 1). For each otherVar argument, upvar makes the variable by that name in the procedure frame given by level (or at global level, if level is #0) accessible in the current procedure by the name given in the corresponding myVar argument. The variable named by otherVar need not exist at the time of the call; it will be created the first time myVar is referenced, just like an ordinary variable. There must not exist a variable by the name myVar at the time upvar is invoked. MyVar is always treated as the name of a variable, not an array element. An error is returned if the name looks like an array element, such as a(b). OtherVar may refer to a scalar variable, an array, or an array element. Upvar returns an empty string.

この upvar 命令は名前呼び出しによる手続函数呼び出しをより簡易に実現する｡又､Tcl 手続函数と同じ様な新しい制御構造をより簡単に実現する｡譬えば､次の手続函数を見られたい: The upvar command simplifies the implementation of call-by-name procedure calling and also makes it easier to build new control constructs as Tcl procedures. For example, consider the following procedure:

    proc add2 name {
        upvar $name x
        set x [expr {$x + 2}]
    }

もし add2 が変数の名前を与える引数と共に起動されると､その変数の値に2を加える[訳註:add2 var の如く､引数は $ を付けず､変数名で呼出すこと]｡ add2 は upvar ではなく uplevel を使って実装させることもできるが､upvar は add2 に対して､より簡単に､呼出し側の枠組み内の変数を使用できる様にする｡ If add2 is invoked with an argument giving the name of a variable, it adds two to the value of that variable. Although add2 could have been implemented using uplevel instead of upvar, upvar makes it simpler for add2 to access the variable in the caller's procedure frame.

namespace eval は､ Tcl の名前付け文脈を変更する別法である(手続函数呼出しに加えて)｡それは､名前空間文脈を表現する棚枠に呼出し枠組みを追加する｡この意味は､それぞれのnamespace eval 命令は uplevel と upvar 命令に関して､他の呼出し水準と看做している｡譬えば､ info level 1 は最外層の手続函数呼出しか最外層の namespace eval 命令(大域名前空間)かを記述する命令を返す｡同様に uplevel #0 は最外層の名前空間内の最頂上水準の記述譜を評価する｡ namespace eval is another way (besides procedure calls) that the Tcl naming context can change. It adds a call frame to the stack to represent the namespace context. This means each namespace eval command counts as another call level for uplevel and upvar commands. For example, info level 1 will return a list describing a command that is either the outermost procedure call or the outermost namespace eval command. Also, uplevel #0 evaluates a script at top-level in the outermost namespace (the global namespace).

もし upvar 変数が設定解除(unset)されると(譬えば､上記の add2 の x )､その設定解除操作は､ upvar 変数ではなく､それが連結している変数に効果を及ぼす｡upvar 変数を設定解除する方法は､それが定義されている手続函数を終了する以外にはない｡但し､他のupvar命令を実行することにより､ upvar 命令の組合せの相手を変更することは可能である｡ If an upvar variable is unset (e.g. x in add2 above), the unset operation affects the variable it is linked to, not the upvar variable. There is no way to unset an upvar variable except by exiting the procedure in which it is defined. However, it is possible to retarget an upvar variable by executing another upvar command.

### TRACES 命令と UPVAR 命令　　　TRACES AND UPVAR

upvar は恐らく､予期しない方法で､追跡とまともに干渉する｡もし､変数追跡が余所の変数 otherVar 上で定義されている場合､追跡は我が変数 myVar を含んでいる動作によって起動される｡但し､追跡手続函数は､余所の変数 otherVar の名前ではなく､我が変数 myVar の名前を渡される｡そこで､次の命令譜の出力は “originalVar” ではなく “localVar” になる: Upvar interacts with traces in a straightforward but possibly unexpected manner. If a variable trace is defined on otherVar, that trace will be triggered by actions involving myVar. However, the trace procedure will be passed the name of myVar, rather than the name of otherVar. Thus, the output of the following code will be “localVar” rather than “originalVar”:

    proc traceproc { name index op } {
        puts $name
    }
    proc setByUpvar { name value } {
        upvar $name localVar
        set localVar $value
    }
    set originalVar 1
    trace variable originalVar w traceproc
    setByUpvar originalVar 2

もし余所の変数 otherVar が配列の要素を参照している場合､我が変数 myVar が利用されようとする時には､配列全体の為に設定された追跡が起動されることはない(しかし､特定の要素の追跡は猶起動される)｡特に､もし配列が env の場合､我が変数 myVar になされた変更が副手順に正しく渡されることはない｡ If otherVar refers to an element of an array, then variable traces set for the entire array will not be invoked when myVar is accessed (but traces on the particular element will still be invoked). In particular, if the array is env, then changes made to myVar will not be passed to subprocesses correctly.

### 用例 EXAMPLE

変数に加算する代わりに､減算する事以外は incr とは同じに動作する decr 命令[訳註:蛇足ながら､incr 命令と同じく呼出時に假引数名に$を付けないこと]: A decr command that works like incr except it subtracts the value from the variable instead of adding it:

    proc decr {varName {decrement 1}} {
        upvar 1 $varName var
        incr var [expr {-$decrement}]
    }

### SEE ALSO

global, namespace, uplevel, variable

### KEYWORDS

context, frame, global, level, namespace, procedure, upvar, variable
Copyright © 1993 The Regents of the University of California.
Copyright © 1994-1997 Sun Microsystems, Inc.